Ubuntu-fr

EricG

Un wallpaper Ubuntu pour vous...

Modération: Image trop grande penser à l'avenir à utiliser la miniature

Dernière modification par Kanor (Le 23/03/2010, à 20:47)

Floyd Pepper

Re : Un wallpaper Ubuntu pour vous...

Salut et merci

---

... J'aurais tendance à ne pas utiliser de smilleys.
Le plus tu t'fais chier, le plus t'es emmerdé.

EricG

Re : Un wallpaper Ubuntu pour vous...

Salut,

Cela flatte mon égo
Tu l'as décentré on dirait ?
Ça en jette.
Toile Libre à l'air bien pour faire un thumb. Je n'y suis pas arrivé avec imageshack mais je n'avais pas envie de chercher.

Gemnoc

Re : Un wallpaper Ubuntu pour vous...

Mais si, c'est tout simple avec Imageshack. Le code est généré automatiquement par le site. Il se trouve dans la colone de droite, sous «Intégrer les miniatures (ou vignettes) de cette image. Tu copie le code pour forum et le colle ici, et hop:

D'ailleurs, avec ton image gigantesque, tu contreviens aux règles du forum, là!

P.S. C'est fait sous Blender, le logo?

Floyd Pepper

Re : Un wallpaper Ubuntu pour vous...

Tu l'as décentré on dirait ?

Oui, 4 clics sous Gimp et le tour est joué, je ne voulais pas que le conky masque une partie de ton chef d'œuvre ...

---

... J'aurais tendance à ne pas utiliser de smilleys.
Le plus tu t'fais chier, le plus t'es emmerdé.

EricG

Re : Un wallpaper Ubuntu pour vous...

@gemnoc
Comme je disais, je n'avais pas envie de chercher sur le moment ; vite fait, vite décidé.
Non, sous POV, à la main, en script. Si vous le voulez, je mets le script dessous.

@Floyd Pepper
... ou l'inverse

Pour essayer :

/* Couleurs normalisées du logo d'Ubuntu */
#declare r = pigment { rgb <201, 0, 22>*(1/255) };
#declare o = pigment { rgb <255, 99, 9>*(1/255) };
#declare j = pigment { rgb <255, 181, 21>*(1/255) };

/* Aspect des couleurs final */
#declare finition = finish { specular 1 roughness .006 ambient .25 diffuse .25 }

/* Textures finales */
#declare rouge = texture { pigment { r } finish { finition } }
#declare orange = texture { pigment { o } finish { finition } }
#declare jaune = texture { pigment { j } finish { finition } }


/* Un bras */
#declare bras =
	intersection
		{
		/* Deux tores, l'un creuse l'autre */
		torus { 20, 5 rotate x*90 }
		torus { 20, 4 rotate x*90 inverse }
		
		/* Limitation par des plans à un tier, avec interstice de 2 */ 
		plane { y, -2 }
		plane { -y, -2 rotate -z*120 }
		
		/* Découpe pour la tête */
		sphere { <-27.5, 0, 0>, 7.5 rotate z*120 inverse }
		
		}
		

/* Finalisation */
#declare logo =
	union
		{
		/* Création des trois bras */
		object { bras texture { rouge } }
		object { bras texture { orange } rotate z*120 }
		object { bras texture { jaune } rotate z*240 }
		/* Création de trois têtes */
		sphere { <-27.5, 0, 0>, 6 texture { orange } }
		sphere { <-27.5, 0, 0>, 6 texture { jaune } rotate z*120 }
		sphere { <-27.5, 0, 0>, 6 texture { rouge } rotate z*240 } }


/*-------------------------------------------*/

object
	{
	logo
	rotate z*15
	rotate y*45
	}

/*-------------------------------------------*/

camera
	{
	location <0, 0, -80>
	look_at <0, 0, 0>
	}

/* Lumière arrière légèrement à droite */
light_source
	{
	<0, 0, 200> 
	rgb <1, 1, 1>
	spotlight point_at <0, 0, 0> radius 20 falloff 30
	rotate y*55
	}

/* Lumière à droite, interstice */
light_source
	{
	<0, 0, 200> 
	rgb <1, 1, 1>
	/* Ombre sur le bras jaune */
	spotlight point_at <0, 0, 0> radius 20 falloff 30
	area_light <16, 0, 0>, <0, 16, 0>, 6, 6
	jitter adaptive 2 circular orient
	rotate y*135
	rotate z*15
	}

/* Lumière arrière légèrement à gauche */
light_source
	{ <0, 0, 200> 
	rgb <1, 1, 1>
	spotlight point_at <0, 0, 0> radius 20 falloff 30
	rotate -y*55 }

/* Lumière arrière légèrement dessous */
light_source
	{ <0, 0, 200> 
	rgb <1, 1, 1>
	spotlight point_at <0, 0, 0> radius 20 falloff 30
	rotate x*55 }

/* Lumière dessous, entaille */
light_source
	{ <0, 0, 200> 
	rgb <1, 1, 1>
	/* Ombre sous la tête rouge */
	spotlight point_at <0, 0, 0> radius 20 falloff 30
	area_light <32, 0, 0>, <0, 32, 0>, 6, 6
	jitter adaptive 2 circular orient
	rotate x*135 }

/* Lumière légèrement dessus */
light_source
	{ <0, 0, 200> 
	rgb <1, 1, 1>
	spotlight point_at <0, 0, 0> radius 20 falloff 30
	rotate -x*55 }

/* Lumière dessus, entaille */
light_source
	{ <0, 0, 200> 
	rgb <1, 1, 1>
	spotlight point_at <0, 0, 0> radius 20 falloff 30
	/* Ombre sur la tête jaune */
	area_light <96, 0, 0>, <0, 96, 0>, 6, 6
	jitter adaptive 2 circular orient
	rotate -x*135 }

Dernière modification par EricG (Le 24/03/2010, à 12:21)

Gemnoc

Re : Un wallpaper Ubuntu pour vous...

@gemnoc
Comme je disais, je n'avais pas envie de chercher sur le moment ; vite fait, vite décidé.

5 secondes pour chercher et trouver... Moi qui croyais manquer de patience!

Non, sous POV, à la main, en script. Si vous le voulez, je mets le script dessous.

Impressionnant!!!

Ça me fait penser à un logiciel de modélisation solide qui fonctionne aussi par script, OpenSCAD.

EricG

Re : Un wallpaper Ubuntu pour vous...

Avec de la méthode et de l'habitude, ça va assez vite, bien plus vite que pour comprendre qu'il faut bouger la souris vers la gauche avec shift enfoncé (quatre sans barreur, séfarades, etc. Enfin bon) sous Blender. J'ai appris POV du temps ou les modeleurs n'existaient pas.

Dernière modification par EricG (Le 24/03/2010, à 18:37)

neophus

Re : Un wallpaper Ubuntu pour vous...

pas mal, tu l'a créer sous quel soft?

Floyd Pepper

Re : Un wallpaper Ubuntu pour vous...

Salut,
La réponse est post #6, je ne connaissais pas alors j'ai :
http://www.google.fr/search?q=povray&ie=utf-8&oe=utf-8&aq=t&rls=com.ubuntu:fr:official&client=firefox-a

---

... J'aurais tendance à ne pas utiliser de smilleys.
Le plus tu t'fais chier, le plus t'es emmerdé.

neophus

Re : Un wallpaper Ubuntu pour vous...

okay je ne connaissais pas

Floyd Pepper

Re : Un wallpaper Ubuntu pour vous...

@EricG
Je m'essaie à comprendre ... 

---

... J'aurais tendance à ne pas utiliser de smilleys.
Le plus tu t'fais chier, le plus t'es emmerdé.