[Résolu]Comment imprimer un chiffre sur deux dans une suite numérique?

metalux · Le 26/01/2017, à 23:51

Bonjour,
Je prépare le Pc d'une personne qui joue au keno et je cherche à extraire le résultat pour l'injecter dans un conky.

j'arrive à obtenir soit cette chaine:

"1":1,"2":4,"3":5,"4":8,"5":9,"6":11,"7":13,"8":17,"9":20,"10":24,"11":33,"12":35,"13":43,"14":47,"15":48,"16":56,"17":58,"18":59,"19":63,"20":68

soit celle-ci:

1 1 2 4 3 5 4 8 5 9 6 11 7 13 8 17 9 20 10 24 11 33 12 35 13 43 14 47 15 48 16 56 17 58 18 59 19 63 20 68

je n'ai eu aucun mal à extraire ceci mais là je bloque. Comment extrait-on uniquement le résultat qui doit être le suivant?

1 4 5 8 9 11 13 17 20 24 33 35 43 47 48 56 58 59 63 68

Par ailleurs, je souhaite l'afficher sur 2 lignes dans le conky, donc soit l'extraction se fait en une fois et le retour à la ligne se fait dans le fichier conky si c'est faisable, soit le script découpe directement en 2 et l'affichage se fait par:

echo -e "chaîne1\nchaîne2"

Voici les lignes permettant de récupérer le résultat:

keno=$(curl -s https://www.fdj.fr/jeux/jeux-de-tirage/keno/resultats | grep tabTirages)
date=$(awk -F'[""]' '{print $6}' <<<$keno)
resultat=$((awk -F'[{}]' '{print $10}') <<<$keno)

ou bien pour la seconde extraction qu'avec les nombres:

resultat=$((awk -F'[{}]' '{print $10}'|  egrep -o '[[:digit:]]*') <<<$keno)

J'ai bien pensé à une boucle pour afficher un nombre sur 2 mais n'y a-t-il pas quelque chose de plus simple ou plus adapté avec sed ou awk par exemple?

Dernière modification par metalux (Le 23/02/2017, à 16:07)

Vobul · Le 27/01/2017, à 00:31

Salut,

Une solution possible avec awk:

export input="1 1 2 4 3 5 4 8 5 9 6 11 7 13 8 17 9 20 10 24 11 33 12 35 13 43 14 47 15 48 16 56 17 58 18 59 19 63 20 68"
 echo $input|tr ' ' \\n|awk 'NR%2==0'

Résultat:

Dernière modification par Vobul (Le 27/01/2017, à 00:32)

MicP · Le 27/01/2017, à 02:25

Bonjour

Je ne sais pas trop bien utiliser awk => c'est certain qu'il y a mieux à faire, mais en attendant…

Ci-dessous pour extraire la date + les numéros sur deux lignes

curl -s https://www.fdj.fr/jeux/jeux-de-tirage/keno/resultats | awk -F[{}] '/var tabTirages/ {print $3,$4}' | awk -F":\"" '{print $2}' | awk -F[\",:] '{print $1"\n"$9,$13,$17,$21,$25,$29,$33,$37,$41,$45"\n"$49,$53,$57,$61,$65,$69,$73,$77,$81,$85}'
Jeudi 26 janvier 2017
3 9 10 17 20 24 27 29 31 39
43 49 52 56 60 61 62 64 66 69

Ci-dessous pour n'extraire que les numéros sur deux lignes

curl -s https://www.fdj.fr/jeux/jeux-de-tirage/keno/resultats | awk -F[{}] '/var tabTirages/ {print $4}' | awk -F[\",:] '{print $4,$8,$12,$16,$20,$24,$28,$32,$36,$40"\n"$4,$48,$52,$56,$60,$64,$68,$72,$76,$80}'
3 9 10 17 20 24 27 29 31 39
3 49 52 56 60 61 62 64 66 69

Il doit y avoir moyen d'utiliser une boucle for dans awk, et je ne sais même pas encore utiliser BEGIN, END de awk

Dernière modification par MicP (Le 27/01/2017, à 02:33)

Watael · Le 27/01/2017, à 02:33

salut,

$ curl -s https://www.fdj.fr/jeux/jeux-de-tirage/keno/resultats | grep tabTirages | awk -F'[{}]' '{print $10}'
"1":1,"2":4,"3":5,"4":8,"5":9,"6":11,"7":13,"8":17,"9":20,"10":24,"11":33,"12":35,"13":43,"14":47,"15":48,"16":56,"17":58,"18":59,"19":63,"20":68

curl -s https://www.fdj.fr/jeux/jeux-de-tirage/keno/resultats \
   | awk -F'[{}]' '/var[[:blank:]]*tabTirages/{rslt = $10}END{ n=split(rslt,ar,","); for(i=1;i<=n;i++){fmt="%s ";if(i==n)fmt="%s";split(ar[i],aar,":");printf(fmt, aar[2])}print ""}'
1 4 5 8 9 11 13 17 20 24 33 35 43 47 48 56 58 59 63 68

edit: en allant un peu plus loin :

wget -qO- "[url]https://www.fdj.fr/jeux/jeux-de-tirage/keno/resultats[/url]" | ./rsltKeno
matin: 3 9 10 17 20 24 27 29 31 39 43 49 52 56 60 61 62 64 66 69
soir: 1 4 5 8 9 11 13 17 20 24 33 35 43 47 48 56 58 59 63 68

avec rsltKeno :

#!/usr/bin/gawk -f

BEGIN{ FS="[{}]"; tirage[1]="matin"; tirage[2]="soir"}
/var[[:blank:]]*tabTirages/{
    rslt[1] = $4; 
    rslt[2] = $10 
}
END{
    for(res in rslt){
        printf("%s: ",tirage[res]);
        n=split(rslt[res],ar,",");
        for(i=1;i<=n;i++){
            fmt = i==n?"%s":"%s "
            gsub("[^:]*:","",ar[i])
            printf(fmt, ar[i])
        }   
        print ""
    }   
}

Dernière modification par Watael (Le 27/01/2017, à 03:59)

MicP · Le 27/01/2017, à 06:59

Bonjour

Grâce à Watael, je viens d'apprendre à faire mon premier script gawk
et du coup, je sais maintenant utiliser les boucles for, ainsi que BEGIN et END

Comme j'ai remarqué que metalux extrayait aussi la date du tirage,
je me suis basé sur le script gawk de Watael pour y ajouter quelques lignes afin de faire afficher aussi la date

EDIT : Voir plus bas les remarques de Watael : il y a tellement mieux à faire que ce que je propose ci-dessous…

#!/usr/bin/gawk -f

BEGIN{ FS="[{}]"; chdate="date"; tirage[1]="matin"; tirage[2]="soir"}
/var[[:blank:]]*tabTirages/{
    chdt    = $3;
    rslt[1] = $4; 
    rslt[2] = $10 
}
END{
    split(chdt,tbl,":");
    split(tbl[2],dte,",");
    gsub("\"","",dte[1]);
    printf("%s: %s\n",chdate,dte[1]);
    for(res in rslt){
        printf("%s: ",tirage[res]);
        n=split(rslt[res],ar,",");
        for(i=1;i<=n;i++){
            fmt = i==n?"%s":"%s "
            gsub("[^:]*:","",ar[i])
            printf(fmt, ar[i])
        }   
        print ""
    }   
}

Comme toujours, pour un débutant comme moi, il est très certainement possible de faire plus propre.

=======

metalux dans son message #1 a écrit :

…Par ailleurs, je souhaite l'afficher sur 2 lignes dans le conky…

Comme il existe le tirage du matin et du soir,
est-ce que tu voudrais obtenir une ligne par tirage <=> 2 lignes,
ou bien est-ce que tu voudrais obtenir chacun des tirages sur deux lignes <=> 5 chiffres par lignes => 4 lignes pour les deux tirages ?

Dernière modification par MicP (Le 28/01/2017, à 11:56)

metalux · Le 27/01/2017, à 08:57

Ouah, je ne m'attendais pas à autant de réponses en si peu de temps! Merci à tous.
Là je pars travailler, je regarderai ça à tête reposée dans les jours à venir et je reviens vers vous si j'ai besoin d'explications.

@MicP

MicP a écrit :

Comme il existe le tirage du matin et du soir,
est-ce que tu voudrais obtenir une ligne par tirage <=> 2 lignes,
ou bien est-ce que tu voudrais obtenir chacun des tirages sur deux lignes <=> 5 chiffres par lignes => 4 lignes pour les deux tirages ?

Je ne savais même pas qu'il y avait un tirage le matin et un le soir, je ne suis pas joueur moi-même.
Donc oui, je pense qu'il faudrait les 2 tirages. Pour l'affichage, j'ai déjà le loto et le PMU aussi c'est pour que l'affichage du keno n'agrandisse pas la taille du conky que je souhaite l'affichage sur plusieurs lignes. Disons que 2 fois 10 nombres pour chaque tirage devrait le faire, quitte à ce que l'affichage "matin" et "soir" se fasse sur la ligne précédente, comme ça ça devrait passer.
Voici une capture de ce que ça donne, sans le keno:

MicP · Le 27/01/2017, à 09:14

Bonjour metalux

Tu devrais essayer de faire un test d'affichage dans le conki avec des N° bidon, juste pour voir ce que ça donne.
Ensuite, on pourra se servir de ce modèle pour formater la sortie du script en fonction des contraintes que tu aura pu définir plus précisément.

Bonne journée, et à bientôt.

Watael · Le 27/01/2017, à 13:22

    split(chdt,tbl,":");
    split(tbl[2],dte,",");
    gsub("\"","",dte[1]);
    printf("%s: %s\n",chdate,dte[1]);

un seul split est nécessaire

gsub("\"","",$3);
split($3,dt,"[:,]");
print "date: "dt[2]

et chdate n'est pas indispensable.
le tableau tirage, lui, l'est pour conserver l'ordre des données, car les tableaux associatifs, qui ne sont pas indexés par un nombre mais une chaîne, sont hashés, et donc l'ordre initial est perdu.
pour mettre les résultats sur plusieurs lignes, et aligner les nombres sur deux chiffres :

fmt = i==n ? "%2d" : i%10 ? "%2d " : "%2d\n"

c'est abscons !
du coup, je me plussoie tout seul.

Dernière modification par Watael (Le 27/01/2017, à 14:29)

MicP · Le 27/01/2017, à 13:47

Bonjour Watael

Super content de lire tes conseils. Je me doutais bien qu'il y avait quelque chose de plus clean à faire avec ces deux split consécutifs.

Il me manque beaucoup de pratique et de connaissances : je n'ai jamais eu de cour de programmation,
mais j'adorais les maths, la physique, la chimie, et l'électronique à été mon hobby depuis mon plus jeune âge.

metalux · Le 28/01/2017, à 00:17

Vous êtes top! Je suis peu dispo ce W.E. pour regarder ça, aussi si je ne donne pas de retours, ce n'est pas que j'ignore vos contributions, ce n'est juste que je n'ai pas eu le temps de m'y attarder. Je reviens dans la semaine.
Bon W.E.

MicP · Le 28/01/2017, à 00:22

Bon WE à toi aussi.

=======
@Watael J'avais reconnu la syntaxe du C, je ne savais pas qu'il était possible de faire des tests conditionnels dans le paramètre de formatage utilisé par printf

Dernière modification par MicP (Le 28/01/2017, à 11:43)

metalux · Le 29/01/2017, à 19:50

Je viens d'essayer de suivre vos conseils et je me suis aperçu de choses manquantes. Il y a également un multiplicateur à extraire et à afficher dans le conky. Un N° Joker également comme pour le loto.
Pour les conseils de Watael ici, la date ne s'affiche pas. J'ai légèrement modifié les scripts pour obtenir l'affichage que je souhaite comme sur l'image ci-dessous:

Voici le script que j'utilise pour l'instant, je vous laisse le corriger, ce n'est pas dans mes cordes:
rsltKeno

#!/usr/bin/gawk -f

BEGIN{ FS="[{}]"; chdate=""; tirage[1]="matin"; tirage[2]="soir"}
/var[[:blank:]]*tabTirages/{
    chdt    = $3;
    rslt[1] = $4; 
    rslt[2] = $10 ;

}
END{
    split(chdt,tbl,":");
    split(tbl[2],dte,",");
    gsub("\"","",dte[1]);
    printf("%s%s\n",chdate,dte[1]);
    for(res in rslt){
        printf("%s: \n",tirage[res]);
        n=split(rslt[res],ar,",");
        for(i=1;i<=n;i++){
            fmt = i==n ? "%2d" : i%10 ? "%2d " : "%2d\n"
            gsub("[^:]*:","",ar[i])
            printf(fmt, ar[i])
        }   
        print ""
    }   
}

Une dernière chose un peu embêtante, pour l'exemple mis en image, le tirage "soir" de la veille s'affiche au lieu de celui du jour, ce qui est normal vu qu'il n'a pas encore été fait. Y-a-t-il moyen de faire en sorte qu'une mention "tirage de la veille" par exemple soit affichée dans ce cas?

Watael · Le 29/01/2017, à 20:07

la date ne s'affiche pas

c'est parce que j'utilisais $3 au lieu de chdt.

ce soir, c'est mort pour faire des tests,
à partir de quelle heure ce comportement est-il observé ?
y a-t-il une indication dans le code de la page du Keno que c'est le tirage de la veille ?

sinon, peut-être en utilisant les Time Functions de gawk...comparer l'heure actuelle avec les heures de tirages ?

metalux · Le 29/01/2017, à 23:23

c'est parce que j'utilisais $3 au lieu de chdt.

C'est Ok. Remplacé $3 par chdt, ça fonctionne

y a-t-il une indication dans le code de la page du Keno que c'est le tirage de la veille ?

Oui, la date est différente: Voici le retour des 2 premiers résultats sur l'exemple de samedi soir et dimanche matin.

var tabTirages = {"2017057":{"dhtir":"Dimanche 29 janvier 2017","numeros":{"1":2,"2":6,"3":10,"4":11,"5":13,"6":15,"7":20,"8":21,"9":24,"10":38,"11":39,"12":41,"13":44,"14":54,"15":56,"16":57,"17":60,"18":63,"19":64,"20":67},"cplm":[],"jokerplus":"9 037 203","video":true,"soustir":"1","type":"new","multiplicateur":2,"couronne":{"1":47,"2":48,"3":15,"4":65,"5":56,"6":36,"7":64,"8":46,"9":6,"10":29,"11":70,"12":14,"13":37,"14":62,"15":25,"16":67,"17":23,"18":3,"19":66,"20":53,"21":1,"22":19,"23":17,"24":18,"25":4,"26":20,"27":8,"28":59,"29":10,"30":22,"31":63,"32":21,"33":69,"34":45,"35":2,"36":27,"37":40,"38":16,"39":35,"40":58,"41":13,"42":42,"43":28,"44":49,"45":38,"46":41,"47":34,"48":60,"49":26,"50":52,"51":24,"52":30,"53":54,"54":50,"55":39,"56":31,"57":33,"58":44,"59":5,"60":68,"61":55,"62":43,"63":57,"64":9,"65":7,"66":32,"67":12,"68":11,"69":61,"70":51}},"2017056":{"dhtir":"Samedi 28 janvier 2017","numeros":{"1":3,"2":6,"3":11,"4":12,"5":13,"6":16,"7":17,"8":20,"9":21,"10":29,"11":30,"12":31,"13":32,"14":37,"15":38,"16":41,"17":46,"18":56,"19":57,"20":64},"cplm":[],"jokerplus":"9 998 249","video":true,"soustir":"2","type":"new","multiplicateur":1,"couronne"

par contre le script ne respecte pas matin et soir, mais dernier et avant-dernier tirage. Maintenant que le nouveau tirage a eu lieu, j'ai dans matin le tirage de ce soir et dans soir le tirage de ce matin.

Watael · Le 30/01/2017, à 00:28

le script ne respecte pas matin et soir, mais dernier et avant-dernier tirage

et ça ne pourrait pas être la solution ?
plutôt que matin et soir, afficher dernier tirage et tirage précédent ?
ou récupérer les dates et afficher les deux si elles sont différentes ?
il y a aussi un numéro d'ordre (2017056, 2017057) qui semble pouvoir être exploité.

metalux · Le 30/01/2017, à 08:50

Oui, ça ne pose pas de problème d'afficher le dernier et avant-dernier tirage. Si 2 tirages ont la même date alors il s'agit du matin et du soir du même jour, si les 2 dates sont différentes, il s'agit de la veille au soir et du matin du jour en cours. Si il y a la possibilité d'afficher la date pour les 2 tirages, on est sûr de quels tirages il s'agit et ça évite toute confusion.

Watael · Le 30/01/2017, à 17:50

#!/usr/bin/gawk -f
function setRefTirage(numeroTirage,heure) {
    gsub("[\":,]","",numeroTirage);
    split(heure,H,"\"");
    RefTirage[numeroTirage]=H[4]
}
function Print(n,dt,nb) {
    split(dt,tAr,"[:,]")
    gsub("\"","",tAr[2])
    if(prevDate){
        if(prevDate != tAr[2])print tAr[2]
    }else{
        prevDate=tAr[2]
        print tAr[2]
    }
    gsub("[\",:]","",n);
    print RefTirage[n]":"
    gsub(",*\"[^:]*:"," ",nb)
    m=split(nb,rslt," ")
    for(i=1;i<=m;i++){
        fmt = i==n ? "%2d" : i%10 ? "%2d " : "%2d\n"
        printf(fmt,rslt[i])
    }
}
BEGIN{
    FS="[{}]"
}
/listDayTirage/{
    setRefTirage($2,$3);
    setRefTirage($4,$5);
}
/var[[:blank:]]*tabTirages/{
    Print($8,$9,$10)
    Print($2,$3,$4)
}

$ wget -qO- "$adrS" | ./monScript.awk 
Dimanche 29 janvier 2017
soir:
 4  5  9 11 12 15 16 19 22 24
28 34 51 54 59 60 62 68 69 70
Lundi 30 janvier 2017
midi:
 2  4  5  8 15 19 22 25 28 32
33 39 49 50 51 54 55 58 63 69
$

pour l'instant le code me plaît.
je verrai dans quelques jours à la relecture.

et ça a l'air de faire ce que tu veux, non ?

Dernière modification par Watael (Le 30/01/2017, à 17:50)

metalux · Le 30/01/2017, à 21:43

Oui, ça fait ce que je veux. Si il y a la possibilité d'ajouter le N° multiplicateur et le N° Joker, tout sera parfait.
merci bien pour ce script

Watael · Le 30/01/2017, à 22:56

oui, c'est possible.
tu peux créer une fonction avec un split et un gsub qui traitera $5 puis $11,
ou modifier la fonction Print pour qu'elle traite un argument supplémentaire.

MicP · Le 31/01/2017, à 06:30

En tout cas, moi qui voulais un cours sur awk je suis aux anges

metalux · Le 04/02/2017, à 15:26

Watael a écrit :

oui, c'est possible.
tu peux créer une fonction avec un split et un gsub qui traitera $5 puis $11,
ou modifier la fonction Print pour qu'elle traite un argument supplémentaire.

Je reviens vers vous, je ne comprends rien à ce qu'il faut faire, je n'ai jamais fais de script gawk et je n'ai pas la concentration nécessaire en ce moment pour pouvoir m'y atteler.
Donc soit je le code simplement avec awk comme j'ai fais pour le loto, soit on l'intègre dans le script gawk mais dans ce cas, j'ai besoin de votre aide.

Sinon il y a un autre problème concernant le codage des polices qui apparaît avec le script gawk que je n'ai pas avec les scripts bash concernant le loto ou le Pmu.
Février s'affiche normalement avec le script bash concernant l'affichage du Loto:

#!/bin/bash
loto=$(curl -s https://www.fdj.fr/jeux/jeux-de-tirage/loto/resultats | grep tabTirages)
date=$(awk -F'[""]' '{print $6}' <<<$loto)
resultat=$((awk -F'[""]' '{print $9}' |  egrep -o '[[:digit:]]*') <<<$loto)
complementaire=$((awk -F'[""]' '{print $11}' |  egrep -o '[[:digit:]]*') <<<$loto)
joker=$((awk -F'[""]' '{print $14}' |  egrep -o '[[:digit:]]*') <<<$loto)
echo -e ""$date"\nNuméros gagnants: "$resultat"\nN° complémentaire: "$complementaire"\nN° Joker: "$joker""

Avec le script gawk concernant le Keno, février s'affiche f\u00e9vrier
Rien n'y fait, j'ai essayé de jouer sur la valeur de override_utf8_locale dans le conky et également sur le codage du script, ça ne change rien. Une idée?

metalux · Le 13/02/2017, à 20:48

Y a-t-il encore quelqu'un pour m'aider?

Watael · Le 13/02/2017, à 21:58

il faut faire des gsub sur "\u00e9" vers "é", et sur "\u00fb" vers "û"
tu vas t'amuser, parce qu'il faut protéger les antislashs, et protéger ces protections.

metalux · Le 13/02/2017, à 22:53

Merci Watael, mais je ne crois pas que ce soit dans mes cordes de corriger cela, déjà que je ne comprends pas grand chose aux scripts gawk.
J'étudierai cela quand j'aurai plus de temps. Je vais essayer autrement à moins que tu puisses m'aider à le faire.

MicP · Le 14/02/2017, à 03:08

…
function Print(n,dt,nb) {
    gsub(/\\u00e9/,"é",dt)
    gsub(/\\u00fb/,"û",dt)
    split(dt,tAr,"[:,]")
…

Ubuntu-fr

Navigation

Liens de recherche

Annonce

#1 Le 26/01/2017, à 23:51

[Résolu]Comment imprimer un chiffre sur deux dans une suite numérique?

#2 Le 27/01/2017, à 00:31

Re : [Résolu]Comment imprimer un chiffre sur deux dans une suite numérique?

#3 Le 27/01/2017, à 02:25

Re : [Résolu]Comment imprimer un chiffre sur deux dans une suite numérique?

#4 Le 27/01/2017, à 02:33

Re : [Résolu]Comment imprimer un chiffre sur deux dans une suite numérique?

#5 Le 27/01/2017, à 06:59

Re : [Résolu]Comment imprimer un chiffre sur deux dans une suite numérique?

#6 Le 27/01/2017, à 08:57

Re : [Résolu]Comment imprimer un chiffre sur deux dans une suite numérique?

#7 Le 27/01/2017, à 09:14

Re : [Résolu]Comment imprimer un chiffre sur deux dans une suite numérique?

#8 Le 27/01/2017, à 13:22

Re : [Résolu]Comment imprimer un chiffre sur deux dans une suite numérique?

#9 Le 27/01/2017, à 13:47

Re : [Résolu]Comment imprimer un chiffre sur deux dans une suite numérique?

#10 Le 28/01/2017, à 00:17

Re : [Résolu]Comment imprimer un chiffre sur deux dans une suite numérique?

#11 Le 28/01/2017, à 00:22

Re : [Résolu]Comment imprimer un chiffre sur deux dans une suite numérique?

#12 Le 29/01/2017, à 19:50

Re : [Résolu]Comment imprimer un chiffre sur deux dans une suite numérique?

#13 Le 29/01/2017, à 20:07

Re : [Résolu]Comment imprimer un chiffre sur deux dans une suite numérique?

#14 Le 29/01/2017, à 23:23

Re : [Résolu]Comment imprimer un chiffre sur deux dans une suite numérique?

#15 Le 30/01/2017, à 00:28

Re : [Résolu]Comment imprimer un chiffre sur deux dans une suite numérique?

#16 Le 30/01/2017, à 08:50

Re : [Résolu]Comment imprimer un chiffre sur deux dans une suite numérique?

#17 Le 30/01/2017, à 17:50

Re : [Résolu]Comment imprimer un chiffre sur deux dans une suite numérique?

#18 Le 30/01/2017, à 21:43

Re : [Résolu]Comment imprimer un chiffre sur deux dans une suite numérique?

#19 Le 30/01/2017, à 22:56

Re : [Résolu]Comment imprimer un chiffre sur deux dans une suite numérique?

#20 Le 31/01/2017, à 06:30

Re : [Résolu]Comment imprimer un chiffre sur deux dans une suite numérique?

#21 Le 04/02/2017, à 15:26

Re : [Résolu]Comment imprimer un chiffre sur deux dans une suite numérique?

#22 Le 13/02/2017, à 20:48

Re : [Résolu]Comment imprimer un chiffre sur deux dans une suite numérique?

#23 Le 13/02/2017, à 21:58

Re : [Résolu]Comment imprimer un chiffre sur deux dans une suite numérique?

#24 Le 13/02/2017, à 22:53

Re : [Résolu]Comment imprimer un chiffre sur deux dans une suite numérique?

#25 Le 14/02/2017, à 03:08

Re : [Résolu]Comment imprimer un chiffre sur deux dans une suite numérique?

Pied de page des forums